include(cmake/targets/dolphin.cmake)

target_compile_definitions(${DUSK_LIBRARY_TARGET_NAME} PUBLIC
  DUSK_WII
)

# Wii save storage method - see src/duskdolphin/save/savedeviceplatform.h.
set(DUSK_SAVE_WII_METHOD "NAND" CACHE STRING
  "Wii save storage: NAND (internal storage via ISFS), CARD (GameCube-\
compatible memory card emulation), or SD (SD card via libfat)"
)
set_property(CACHE DUSK_SAVE_WII_METHOD PROPERTY STRINGS "NAND" "CARD" "SD")

target_compile_definitions(${DUSK_LIBRARY_TARGET_NAME} PUBLIC
  DUSK_SAVE_WII_METHOD_${DUSK_SAVE_WII_METHOD}
)

# Generate Homebrew Channel meta.xml from project identity variables
string(TIMESTAMP DUSK_BUILD_DATE "%Y%m%d000000" UTC)
configure_file(
  "${CMAKE_SOURCE_DIR}/docker/dolphin/meta.xml.in"
  "${DUSK_BUILD_DIR}/meta.xml"
  @ONLY
)

# ISO post-build: produce NTSC-J, NTSC-U and PAL disc images
if(DUSK_DOLPHIN_BUILD_TYPE STREQUAL "ISO")
  add_custom_command(TARGET ${DUSK_BINARY_TARGET_NAME} POST_BUILD
    COMMAND ${Python3_EXECUTABLE}
            "${CMAKE_SOURCE_DIR}/tools/makedolphiniso.py"
            "WII"
            "${DUSK_BINARY_TARGET_NAME_DOL}"
            "${DUSK_ASSETS_ZIP}"
            "${DUSK_GAME_NAME}"
            "${DUSK_BUILD_DIR}"
    COMMENT "Building Wii ISO images (NTSC-J, NTSC-U, PAL)"
  )
endif()