class_name EventConversation extends "res://scripts/Event/Flow/EventGroup.gd"

@export var startPauseType:PauseSystem.PauseType = PauseSystem.PauseType.ENTITY_PAUSED
@export var endPauseType:PauseSystem.PauseType = PauseSystem.PauseType.NOT_PAUSED

@export var entities:Array[Entity] = []

@export var pauseInteractee:bool = true
@export var pauseInteractor:bool = true
@export var turnInteractee:bool = true
@export var turnInteractor:bool = true

func start() -> void:
	# Turn events
	if interactee != null && interactor != null:
		if pauseInteractee && turnInteractee:
			var turn = EventEntityTurn.new()
			turn.entity = interactee
			turn.direction = interactee.getDirectionToFace(interactor.position)
			addExtraEvent(turn, 0)

		if pauseInteractor && turnInteractor:
			var turn = EventEntityTurn.new()
			turn.entity = interactor
			turn.direction = interactor.getDirectionToFace(interactee.position)
			addExtraEvent(turn, 0)

	# Create start pause event
	var startPause = EventPause.new()
	startPause.pauseType = startPauseType
	startPause.entities = entities
	startPause.includeInteractee = pauseInteractee
	startPause.includeInteractor = pauseInteractor
	addExtraEvent(startPause, 0)

	# Create end pause event.
	var endPause = EventPause.new()
	endPause.pauseType = endPauseType
	endPause.entities = entities
	endPause.includeInteractee = pauseInteractee
	endPause.includeInteractor = pauseInteractor
	addExtraEvent(endPause, -1)

	# Pass off to event group
	super.start()